robotframework-selenium2accessibility 0.2.1

安装

$ pip install robotframework-selenium2accessibility

示例测试

*** Settings ***

Resource  Accessibility/wavetoolbar.robot
Resource  Accessibility/contrastchecker.robot

Suite setup  Run keywords
...  Open accessibility test browser  Maximize Browser Window
Suite teardown  Close all browsers

*** Test Cases ***

Test single page
     [Documentation]  Single page test could interact with the target
     ...              app as much as required and end with triggering
     ...              the accessibility scan.
     Go to  http://www.plone.org/
     Check WAVE accessibility errors

Test multiple pages
    [Documentation]  Template based test can, for example, take a list
    ...              of URLs and perform accessibility scan for all
    ...              of them. While regular test would stop for the
    ...              first failure, template based test will just jump
    ...              to the next URL (but all failures will be reported).
    [Template]  Check both WAVE and color contrast
    http://www.plone.org/  wave=0  contrast=6
    http://www.drupal.org/  wave=0  contrast=5
    https://joomla.net.cn/  wave=0  contrast=9
    http://www.wordpress.org/  wave=1  contrast=5

*** Keywords ***

Check both WAVE and color contrast
    [Arguments]  ${url}  ${wave}=0  ${contrast}=0
    Should not exceed maximum WAVE errors  ${url}  ${wave}
    Should not exceed maximum color contrast issues  ${url}  ${contrast}

Should not exceed maximum WAVE errors
    [Arguments]  ${url}  ${max}
    ${errors} =  Count WAVE accessibility errors  ${url}
    Should be true  ${errors} <= ${max}
    ...  WAVE Toolbar reported ${errors} errors for ${url}

Should not exceed maximum color contrast issues
    [Arguments]  ${url}  ${max}
    ${errors} =  Count color contrast issues  ${url}
    Should be true  ${errors} <= ${max}
    ...  WCAG Contrast checker reported ${errors} issue for ${url}

运行

$ pybot demo.robot

阅读文档以获取更多信息。

0.2.1 (2013-09-28)

• 更新了变更日志。

0.2.0 (2013-09-28)

• 重命名为robotframework-selenium2accessibility。一些与WAVE相关的关键字被重命名，以避免未来关键字名称中的命名空间冲突。请参阅文档了解当前关键字。

• 添加了WCAG对比度检查器、集成和关键字。

0.1.3 (2013-05-26)

• 修复了仅当WAVE工具栏报告错误时才获取页面截图的问题。

0.1.2 (2013-05-26)

• 更新了文档。

0.1.1 (2013-05-25)

• 修复了打包问题（从README中删除了非ASCII字符）

0.1.0 (2013-05-25)

• 第一个预发布版